It should look something like this when edited
@Echo off
echo ------------------------------------------
echo --- This will allow SupCom to use more ---
echo ------ than 2GB addressable space --------
echo ------------------------------------------
echo.
echo.
echo Make a backup of your original supremecommander.exe.
echo Please make sure that the supremecommander.exe has been copied to this folder.
echo Then press any key to continue.
pause > nul
:menu
cls
echo ------------------------------------------
echo --- This will allow SupCom to use more ---
echo ------ than 2GB addressable space --------
echo ------------------------------------------
echo.
echo.
echo Choose what to do with large address header...
echo.
choice /n /c:arvde Choose (A) to Add, (R) to Remove, (V) to View current header, (D) for directions, or (E) to exit program:
REM check for file
IF NOT EXIST XR_3DA.exe goto exitout
if errorlevel 5 exit
if errorlevel 4 goto directions
if not errorlevel 4 if errorlevel 3 goto view
if not errorlevel 3 if errorlevel 2 goto remove
if not errorlevel 2 if errorlevel 1 goto add
:directions
cls
echo This allows you to alter the header of the executable to allow supcom to address more than 2GB of RAM.
echo.
echo Add - adds the functionality
echo.
echo Remove - removes the functionality (or use a backed up original supremecommander.exe)
echo.
echo View - dumps the headers of the executable. When viewing the dump scroll all the way up
echo and look for the line that says "Application can handle large (>2GB) addresses".
echo This means the application can now address more than 2GB and it is enabled.
echo.
echo.
echo *Remember to edit your boot.ini to add the /3GB switch allowing XP to use 3GB for applications.
echo.
echo.
pause
goto menu
:view
cls
dumpbin /headers XR_3DA.exe
echo.
echo ______________________________________________________________________
echo INSTRUCTIONS...
echo.
echo Scroll to the top and look for section "FILE HEADER VALUES".
echo Then look for a line in that section that says "Application can handle large (>2GB) addresses".
echo If you see that line then the executable is enabled to handle greater than 2GB, you are done.
echo.
pause
goto menu
:remove
cls
editbin /LARGEADDRESSAWARE:no XR_3DA.exe
echo Large Address Aware has been removed.
echo.
pause
goto menu
:add
cls
editbin /LARGEADDRESSAWARE XR_3DA.exe
echo Large Address Aware has been enabled.
echo.
pause
goto menu
:exitout
cls
echo The XR_3DA.exe has not been copied to this folder.
echo Press any key to exit.
pause > nul
exit
